-- hamm.sa basic class for Hamming problem from Salishan book.
-- use with shamm.sa for serial solution.
-- used with phamm.sa, hmerge.sa for first parallel solution.

class HAMM is
  attr primes:ARRAY{INT};
  private attr stream:ARRAY{A_QUEUE{INT}};
  attr  n,bound:INT;				--n =#primes>1

create(bd:INT, pr:ARRAY{INT}):SAME is 
    res::=new;
    res.primes:=pr;
    res.bound:=bd;
    res.n:=pr.asize;
    res.stream:=#(pr.asize);
    loop i::=pr.ind!; res.stream[i]:=#(bd) end; --bd esitmates size
    return res;  end; -- create

generate!:INT is
    out:INT;			
    loop i::=primes.ind!; stream[i].enq(primes[i]) end;

    loop  
      out:=bound;
      loop i::=primes.ind!; out:=out.min(stream[i].top) end; 
      if out=bound then quit else yield out end;	--then enq multiples

      loop i::=primes.ind!;			-- update the streams
	t::=out*primes[i];
	if t<bound then stream[i].enq(t) end;
	if stream[i].top = out then x::=stream[i].deq;
	  if stream[i].is_empty then stream[i].enq(bound)  end   
	  end; -- outer if 
        end; -- loop to update
      end; --  outermost loop 
     end; -- generate
 end; -- HAMM

-- shamm.sa test class for serial hamming problem
-- compile with hamm.sa

class MAIN is
  attr primes:ARRAY{INT};
  attr h:HAMM;

  main is
     primes:=#(4);
     bound::=32;
     primes[0]:=2; primes[1]:=3;  primes[2]:=7;  primes[3]:=11;

    h:=#(bound,primes);
    #OUT  + 1 + '\n';
    loop #OUT + h.generate! + '\n' end;
    
    end; --main
  end; --MAIN